Text copy: I have a problem with the text handling in transaction IW32. My goal is to copy the header text into the first item text. Can you please tell me how to achieve this?
We suggest you use the Copy/Paste function (Windows clipboard) in your InputScript. A sample script looks as follows:

// reset variable

Set V[iwtext=""]

// Set title during InputScript processing

Set V[mytitle] "Please wait.... Order text is being copied"

Screen SAPLCOIH.3000

Title "&V[mytitle]"

// Long text display?

if X[LTEXT]

goto continue1

endif

// Display long text

Enter "=LTHE"

Screen SAPLCOIH.3000

Title "&V[mytitle]"

label continue1

// tab "Operations" ?

if Q[Page=Operations]

goto continue2

endif

// switch to "Operations" tab

Enter "=VGUE"

Screen SAPLCOIH.3000

Title "&V[mytitle]"

label continue2

CopyText fromScreen=X[LTEXT] toText="iwtext"

// put cursor on button in first table row

SetCursor cell[Table,LT,1]

Enter "=LATX"

// PC editor / word

Screen SAPLSTXX.2102

Title "&V[mytitle]"

Enter "=XEDC" // Change editor

Screen SAPLSTXX.1100

Title "&V[mytitle]"

Enter "/14" // Delete text

// Confrim text deletion

Screen SAPLSPO1.0100

Title "&V[mytitle]"

Enter "=YES"

Screen SAPLSTXX.1100

Title "&V[mytitle]"

// Text to Windows clipboard

CopyText fromText="iwtext" -toClipboard

Enter "=EIAC" // Insert text from clipboard

Screen SAPLSTXX.1100

Title "&V[mytitle]"

// return

Enter "/3"